AROS-Exec :: Forum

Re: My Computer for Aros [by amiga]

Thu, 11 Oct 2018 21:00:30 -0500

General chat::My Computer for Aros
Ciao sabbate some time ago I sent you a PM on Amiganews!

---------

Ciao sabbate tempo fa ti ho inviato un PM su Amiganews!

Re: info datatype (Amiga OS) [by mmartinka]

Wed, 10 Oct 2018 20:33:20 -0500

General chat::info datatype (Amiga OS)
Quote:

amiga wrote: Ciao mmartinka, Google Translator non aiuta a capire.

I understand, but I can not help. My English is tragic and it will not be better ... <img alt="Very Happy" border="0" src="http://aros-exec.org/uploads/smil3dbd4d4e4c4f2.gif" title="Very Happy" />

Re: AROS on classic m68k [by wawa]

Mon, 08 Oct 2018 07:50:39 -0500

Development (General)::AROS on classic m68k
not sure if such an "object oriented" approach is not an overkill when applied in every case, but i would leave it to experienced developers to decide. apparent fact remains, that vampire asm driver seems to work reasonably fast with aros.

Re: ZX Spectrum datatype test [by mmartinka]

Sun, 07 Oct 2018 18:26:41 -0500

General chat::ZX Spectrum datatype test
Sam Coupé - mode 4 screen

Re: USB joystick and posseidon [by DizzyOfCRN]

Sun, 07 Oct 2018 14:31:56 -0500

General chat::USB joystick and posseidon
I've been trying to make a XInput Gamepad from one of my ST-boards...

The way Windows sets the drivers up is driving me crazy, I'm deleting registry entries and un-installing from device manager.

I'm unable to make Windows recognize my spoofing attempts when cloning the Logitech F310, it's all the same descriptors and all...

On Linux and on AROS my spoofing is ok, but not on Windows 7

I've put a serial port on my ST-board and this is what we get on AROS when trying to get the bitmask:

Parse req->bmRequest 0xc1 (Device to Host)
Parse req->bRequest 0x01
Parse req->wValue 0x0100
Parse req->wIndex 0x0000
Parse req->wLength 0x0014
USB_REQ_RECIPIENT_INTERFACE:
USB_REQ_TYPE_STANDARD:
USBD_StdItfReq->USBD_OK;

That's this code calling:

psdPipeSetup(nch->nch_EP0Pipe, URTF_IN|URTF_VENDOR|URTF_INTERFACE, 0x01, 0x0100, 0x00);

do {
ioerr = psdDoPipe(nch->nch_EP0Pipe, ep0buf, 20);
} while(ioerr);

On windows on the other hand I get this and then the board hangs:

Parse req->bmRequest 0xc1 (Device to Host)
Parse req->bRequest 0x01
Parse req->wValue 0x0100
Parse req->wIndex 0x0005 <- Notice this!
Parse req->wLength 0x0014
USB_REQ_RECIPIENT_INTERFACE:
USB_REQ_TYPE_STANDARD:
USBD_StdItfReq->

I think they deliberately mess things up (or my ST-board code is messed), I can sometimes get the spoofing board be recognized by windows if I insert the REAL F310 board before and try enough times, but then Windows just uses the registry keys to set the gamepad up.

Re: A basic linked-list class [by PortablE]

Sun, 07 Oct 2018 13:19:38 -0500

PortablE::A basic linked-list class
Attaching files doesn't seem to work, so here is a copy of those modules:

cBasicList.e


/* CSH/cBasicList.e 12-11-2016 by Chris Handley

    A list implementation which is 'as simple as possible', while still supporting sub-classing, as well as removal/insertion of multiple nodes in one go.

    

    Lists are circular, and always contain a special 'empty' node after any normal nodes.

    This 'empty' node is known as the "pastEnd" node, since it is past the end of the list.

    NEVER remove this node from the list (but it can be used to mark the end of a range of nodes that should be removed).

    

    Optimisations are certainly possible, but at the expense of less readable code and/or a more complex interface.

    At which point it would no-longer be 'as simple as possible'!  (And it's unlikely your program will be noticably faster...)

    Still, this module should be a good starting point for your own list classes.

*/

/* Public methods of *cBasicList*:

    new()

    infoStart()   RETURNS   start:PTR TO cBasicNode

    infoPastEnd() RETURNS pastEnd:PTR TO cBasicNode

    create() RETURNS node:PTR TO cBasicNode

    destroy(first:PTR TO cBasicNode, pastLast=NIL:PTR TO cBasicNode)

    ->helper methods:

    isEmpty() RETURNS isEmpty:BOOL

     append(nodes:PTR TO cBasicNode)

    prepend(nodes:PTR TO cBasicNode)

*/

/* Public methods of *cBasicNode*:

    infoNext() RETURNS next:PTR TO cBasicNode

    infoPrev() RETURNS prev:PTR TO cBasicNode

    beforeInsert(nodes:PTR TO cBasicNode)

     afterInsert(nodes:PTR TO cBasicNode)

    remove(pastLast=NIL:PTR TO cBasicNode) RETURNS nodes:PTR TO cBasicNode

    ->helper methods:

    read() RETURNS data

*/



/*****************************/



CLASS cBasicList

    ->circular list

    pastEnd:PTR TO cBasicNode    ->empty node after last 'real' node in list

ENDCLASS



PROC new() OF cBasicList

    self.pastEnd := self.create()

ENDPROC



PROC end() OF cBasicList

    IF self.pastEnd THEN END self.pastEnd.next

    SUPER self.end()

ENDPROC



PROC infoStart()   OF cBasicList IS self.pastEnd.next



PROC infoPastEnd() OF cBasicList IS self.pastEnd



PROC create() OF cBasicList RETURNS node:PTR TO cBasicNode

    DEF newNode:OWNS PTR TO cBasicNode

    

    newNode := self.makeNode() ; newNode.new()

    node := newNode

    node.prev := node

    node.next := PASS newNode

ENDPROC



PROC destroy(first:PTR TO cBasicNode, pastLast=NIL:PTR TO cBasicNode) OF cBasicList

    DEF nodes:PTR TO cBasicNode

    IF nodes := first.remove(pastLast) THEN END nodes.next

ENDPROC



->helper methods

PROC isEmpty() OF cBasicList RETURNS isEmpty:BOOL IS self.pastEnd.next = self.pastEnd

PROC  append(nodes:PTR TO cBasicNode) OF cBasicList IS self.pastEnd.beforeInsert(nodes)

PROC prepend(nodes:PTR TO cBasicNode) OF cBasicList IS self.pastEnd.afterInsert(nodes)



->PROTECTED

PROC makeNode() OF cBasicList RETURNS node:OWNS PTR TO cBasicNode

    NEW node

ENDPROC



/*****************************/



CLASS cBasicNode

    next:OWNS PTR TO cBasicNode

    prev:     PTR TO cBasicNode

ENDCLASS



->PROTECTED

PROC new() OF cBasicNode IS EMPTY



PROC end() OF cBasicNode

    DEF node:OWNS PTR TO cBasicNode, next:OWNS PTR TO cBasicNode

    

    ->destroy later nodes, without using the stack

    self.prev.next := NIL

    next := PASS self.next

    WHILE next

        node := PASS next

        next := PASS node.next

        END node

    ENDWHILE

    

    SUPER self.end()

ENDPROC



PROC infoNext() OF cBasicNode IS self.next



PROC infoPrev() OF cBasicNode IS self.prev



->insert the supplied node(s) before us

PROC beforeInsert(nodes:PTR TO cBasicNode) OF cBasicNode

    DEF firstNodes:OWNS PTR TO cBasicNode, lastNodes:PTR TO cBasicNode, beforeInsert:PTR TO cBasicNode, afterInsert:OWNS PTR TO cBasicNode

    

    IF nodes = NIL THEN RETURN

    

    lastNodes  := nodes.prev

    firstNodes := PASS lastNodes.next    ->nodes

    beforeInsert := self.prev

    afterInsert  := PASS beforeInsert.next    ->self

    

    firstNodes.prev  := beforeInsert

    afterInsert.prev := lastNodes

    beforeInsert.next := PASS firstNodes

    lastNodes.next    := PASS afterInsert

ENDPROC



->insert the supplied node(s) after us

->NOTE: Inserting after the pastEnd node will put the nodes at the START of the list!

PROC afterInsert(nodes:PTR TO cBasicNode) OF cBasicNode

    DEF firstNodes:OWNS PTR TO cBasicNode, lastNodes:PTR TO cBasicNode, beforeInsert:PTR TO cBasicNode, afterInsert:OWNS PTR TO cBasicNode

    

    IF nodes = NIL THEN RETURN

    

    lastNodes  := nodes.prev

    firstNodes := PASS lastNodes.next    ->nodes

    beforeInsert := self

    afterInsert  := PASS self.next

    

    firstNodes.prev  := beforeInsert

    afterInsert.prev := lastNodes

    beforeInsert.next := PASS firstNodes

    lastNodes.next    := PASS afterInsert

ENDPROC



->remove the current node from the list, or a range of nodes if "pastLast" is supplied

->NOTE: It will return NIL for an empty range (i.e. when "pastLast" is the same as the current node).

PROC remove(pastLast=NIL:PTR TO cBasicNode) OF cBasicNode RETURNS nodes:PTR TO cBasicNode

    DEF firstNodes:OWNS PTR TO cBasicNode, lastNodes:PTR TO cBasicNode, beforeRemove:PTR TO cBasicNode, afterRemove:OWNS PTR TO cBasicNode

    

    IF self = pastLast THEN RETURN NIL

    

    nodes := self

    

    firstNodes := PASS self.prev.next    ->self

    lastNodes  := IF pastLast THEN pastLast.prev ELSE self

    beforeRemove := firstNodes.prev

    afterRemove  := PASS lastNodes.next

    

    firstNodes.prev  := lastNodes

    afterRemove.prev := beforeRemove

    beforeRemove.next := PASS afterRemove

    lastNodes.next    := PASS firstNodes

ENDPROC



->helper methods

PROC read() OF cBasicNode RETURNS data IS 0



/*****************************/

cBasicList_STRING.e


/* CSH/cBasicList_STRING.e 12-11-2016

    A sub-class of cBasicList for STRINGs.

*/

/* Public methods of *cBasicList_STRING*:

    new()

    infoStart()   RETURNS   start:PTR TO cBasicNode_STRING

    infoPastEnd() RETURNS pastEnd:PTR TO cBasicNode_STRING

    create(string=NILS:OWNS STRING) RETURNS node:PTR TO cBasicNode_STRING

    destroy(first:PTR TO cBasicNode, pastLast=NIL:PTR TO cBasicNode)

    ->helper methods:

    isEmpty() RETURNS isEmpty:BOOL

     append(nodes:PTR TO cBasicNode)

    prepend(nodes:PTR TO cBasicNode)

*/

/* Public methods of *cBasicNode_STRING*:

    infoNext() RETURNS next:PTR TO cBasicNode_STRING

    infoPrev() RETURNS prev:PTR TO cBasicNode_STRING

    beforeInsert(nodes:PTR TO cBasicNode)

     afterInsert(nodes:PTR TO cBasicNode)

    remove(pastLast=NIL:PTR TO cBasicNode) RETURNS nodes:PTR TO cBasicNode_STRING

    ->helper methods:

    read() RETURNS data:STRING

*/

/* Public members of *cBasicNode_STRING*:

    data:OWNS STRING

*/



PUBLIC MODULE '*cBasicList'



/*****************************/



CLASS cBasicList_STRING OF cBasicList

ENDCLASS



PROC new() OF cBasicList_STRING

    SUPER self.new()

    self.pastEnd::cBasicNode_STRING.data := NEW ''

ENDPROC



PROC infoStart() OF cBasicList_STRING IS SUPER self.infoStart()::cBasicNode_STRING



PROC infoPastEnd() OF cBasicList_STRING IS self.pastEnd::cBasicNode_STRING



PROC create(string=NILS:OWNS STRING) OF cBasicList_STRING RETURNS node:PTR TO cBasicNode_STRING

    node := SUPER self.create()::cBasicNode_STRING

    node.data := PASS string

ENDPROC



->PROTECTED

PROC makeNode() OF cBasicList_STRING RETURNS node:OWNS PTR TO cBasicNode_STRING

    NEW node

ENDPROC



/*****************************/



CLASS cBasicNode_STRING OF cBasicNode PUBLIC

    data:OWNS STRING

ENDCLASS



PROC end() OF cBasicNode_STRING

    END self.data

    SUPER self.end()

ENDPROC



PROC infoNext() OF cBasicNode_STRING IS self.next::cBasicNode_STRING



PROC infoPrev() OF cBasicNode_STRING IS self.prev::cBasicNode_STRING



PROC remove(pastLast=NIL:PTR TO cBasicNode) OF cBasicNode_STRING RETURNS nodes:PTR TO cBasicNode_STRING

    nodes := SUPER self.remove(pastLast)::cBasicNode_STRING

ENDPROC



PROC read() OF cBasicNode_STRING IS self.data

cBasicList_STRING_test.e


MODULE '*cBasicList_STRING'



PROC main()

    DEF list:OWNS PTR TO cBasicList_STRING, node:PTR TO cBasicNode_STRING, floating:PTR TO cBasicNode_STRING

    

    ->build a list

    NEW list.new()

    list.append(list.create(NEW 'Hello '))

    list.append(list.create(NEW 'new '))

    list.append(list.create(NEW 'world! '))

    printList(list)        ->Hello new world! 

    

    ->do some tests

    node := list.infoStart()

    floating := node.remove()

    list.infoPastEnd().beforeInsert(floating)

    printList(list)        ->new world! Hello 

    

    node := list.infoPastEnd().infoPrev()

    floating := node.remove()

    list.infoStart().beforeInsert(floating)

    printList(list)        ->Hello new world! 

    

    node := list.infoStart()

    floating := node.remove()

    list.infoPastEnd().afterInsert(floating)

    printList(list)        ->Hello new world! 

    

    node := list.infoStart().infoNext()

    floating := node.remove()

    list.infoStart().beforeInsert(floating)

    printList(list)        ->new Hello world! 

    

    node := list.infoStart()

    floating := node.remove(list.infoPastEnd().infoPrev())

    list.infoPastEnd().beforeInsert(floating)

    printList(list)        ->world! new Hello 

    

    Print('Finished.\n')

FINALLY

    PrintException()

    

    END list

ENDPROC



PROC printList(list:PTR TO cBasicList_STRING)

    DEF pastEnd, node:PTR TO cBasicNode_STRING

    

    pastEnd := list.infoPastEnd()

    node := list.infoStart()

    WHILE node <> pastEnd

        Print(node.data)    ->or Print(node.read())

        node := node.infoNext()

    ENDWHILE

    Print('\n')

ENDPROC

About the undocument PASS & NULL keywords, and the barely documented OWNS ! [by PortablE]

Sun, 07 Oct 2018 12:56:43 -0500

PortablE::About the undocument PASS & NULL keywords, and the barely documented OWNS !
(Originally posted on 15-11-2016 to amigacoding.de)

If you are interested in understanding the code of my recently-posted cBasicList.e module, or possibly some of my other modules in PEmodules:CSH, then it may help to understand the "OWNS", "PASS" & "NULL" keywords. "OWNS" only get's a brief mention in the Standard Functionality guide, while "PASS" & "NULL" have been completely UNdocumented until now...

If you see "OWNS" as part of a variable's (or object member's) type, you can safely ignore it, because that is what PortablE currently does! However, it is a hint that variable has ownership (i.e. deallocation responsibility) for that particular pointer (or array or e-string or e-list). If it's part of a local variable, then usually that variable should be ENDed when the procedure finishes. If it's part of an object member, then that member should be ENDed as part of the object's end() method.

If you see "OWNS" as part of a parameter or return variable, then it's a hint that ownership (i.e. deallocation responsibility) is being passed into or out of that procedure.

What about "PASS"? You cannot ignore this, because it actually does something! Here is an example:
Quote:

DEF var1:OWNS PTR TO example, var2:OWNS PTR TO example
var2 := PASS var1

What this does is to pass ownership from var1 to var2. "PASS" does this by evaluating to the original value of "var1" after it has assigned NIL to var1. This ensures that the pointer is only ever owned by one variable (var1 or var2), and so you cannot get into a situation where your program tries to destroy the same object twice. Most of the time you can imagine the above code as equivalent to this:
Quote:

DEF var1:OWNS PTR TO example, var2:OWNS PTR TO example
var2 := var1
var1 := NIL

HOWEVER, this simple story is not quite accurate, and so here's what actually happens:
Quote:

DEF var1:OWNS PTR TO example, var2:OWNS PTR TO example, temp:PTR TO example
temp := var1
var1 := NIL
var2 := temp

When would this make a difference? If you tried to be clever & do something like this:
Quote:

var1.member := PASS var1

You MIGHT imagine that var1 get's stored in it's own member, before it get's NILed... but in actual fact it will lead to a crash, because var1 get's NILed before the assignment occurs, so the code would end-up trying to assign to the member of a NIL pointer! I should probably make PortablE detect & warn about these kinds of situations, at least once "PASS" becomes a properly documented part of the language.

The "NULL" keyword is somewhat similar to "OWNS" in that it is used as part of a variables type, but is currently ignored by PortablE! It is only used with procedure parameters (or possibly return variables). When you see it used with a procedure parameter, it is an indication that parameter is allowed to be NIL. i.e. The procedure will function just fine if you pass it NIL or NILA (as appropriate). For example:
Quote:

PROC example(param1:NULL PTR TO cBasicNode)

Re: AROS Laptop DELL latitiude D520 [by nikolaos]

Sun, 07 Oct 2018 09:54:41 -0500

General chat::AROS Laptop DELL latitiude D520
The_Reaper: I'm not a developer and it is a difficult task. If you have a lot of money, maybe you could find someone to do it.

Re: Checkmate A1500 Plus Kickstarter funded which is good for AROS [by cavemann]

Sat, 06 Oct 2018 20:29:22 -0500

General chat::Checkmate A1500 Plus Kickstarter funded which is good for AROS
It would have been easier to run the gauntlet. Well done! Congratulations

Re: Net Bubble 0.9.1 error [by amiga]

Sat, 06 Oct 2018 16:00:19 -0500

General chat::Net Bubble 0.9.1 error
Net-Bubble also works well on AROS 68k.

If you need it, I've created a nice DualPNG icon, i attach icon file

Test Video: Net-Bubble AfA-OS 68k
https://youtu.be/oBLxI6weJDQ

Test Video: Net-Bubble + Audio AROS x86
https://youtu.be/PAHFVKQLNXM